***********************************************************
*
* PMEG3002AELD
*
* Nexperia
*
* 30 V, 0.2 A low VF MEGA Schottky barrier rectifier
* IFmax = 200mA (average)
* VRmax = 30V
* VFmax = 480mV    @ IF = 200mA
* IRmax = 10µA     @ VR = 10V
* 
*
*
*
* Package pinning does not match Spice model pinning.
* Package: SOD882D
*
* Package Pin 1: Cathode
* Package Pin 2: Anode
*
*
* Extraction date (week/year): #
* Simulator: SPICE3
*
***********************************************************
*
* The resistor R1 and the diode D2  
* do not reflect physical devices.
* Instead they improve modeling in the 
* forward and reverse mode of operation.
*
.SUBCKT PMEG3002AELD 1 2       
R1 1 2 4E+006
D1 1 2
+ DIODE1
D2 1 2  
+ DIODE2
*
.MODEL DIODE1 D 
+ IS = 8E-007   
+ N = 1 
+ BV = 41.46    
+ IBV = 0.0021  
+ RS = 0.5      
+ CJO = 3.463E-011      
+ VJ = 0.18     
+ M = 0.38      
+ FC = 0
+ TT = 0
+ EG = 0.69     
+ XTI = 2       
.MODEL DIODE2 D 
+ IS = 5E-010   
+ N = 1 
+ RS = 0.9      
.ENDS
*