***********************************************************
*
* PESD24VL1BA
*
* Nexperia
*
* Low capacitance bidirectional ESD protection diodes in SOD323
* VRWM = 24V
* Cd   = 11pF @ f = 1MHz, VR = 0V
* IRM  = 50nA @ VRWM = 24V
* 
* 
*
*
* Package pinning does not match Spice model pinning.
* Package: SOD323
* 
* Package Pin 1: Cathode D1
* Package Pin 2: Cathode D2
*
*
*
* Extraction date (week/year): #
* Simulator: SPICE3
*
***********************************************************
*
* The resistors R1 and R2 do not 
* reflect physical devices but 
* improve only modeling in the 
* reverse mode of operation.
*
.SUBCKT PESD24VL1BA 1 2
R1 1 11 1E+012
R2 2 11 5E+012
D1 11 1
+ DIODE1
D2 11 2
+ DIODE2
*
.MODEL DIODE1 D
+ IS = 3E-012
+ N = 0.1
+ BV = 27
+ IBV = 1E-008
+ RS = 40
+ CJO = 1E-008
+ VJ = 0.6
+ M = 0.1
+ FC = 0.5
+ TT = 0
+ EG = 1.1
+ XTI = 3
.MODEL DIODE2 D
+ IS = 1E-014
+ N = 1.9
+ BV = 26.9
+ IBV = 1E-008
+ RS = 10
+ CJO = 1.126E-011
+ VJ = 1.6
+ M = 0.28
+ FC = 0
+ TT = 0
+ EG = 1.1
+ XTI = 3
.ENDS
*