***********************************************************
*
* PBSS5580PA
*
* Nexperia
*
* Low VCEsat PNP (BISS) Transistor
* IC   = 4,5 A
* VCEO = 80 V 
* hFE  = typ.225  @ 2V/2A
*
*
*
*
* Package pinning does not match Spice model pinning.
* Package: SOT 1061
* 
* Package Pin 1: Base 
* Package Pin 2: Emitter
* Package Pin 3: Collector
*
*
* Extraction date (week/year): 20/2009
* Spicemodel does not include temperature dependency
*
**********************************************************
*#
* Please note: Diode D1/D2, Transistor Q2 and Resistor RQ 
* are dedicated to improve modeling of quasi
* saturation area and reverse mode operation
* and do not reflect physical devices.
* 
.SUBCKT PBSS5580PA 1 2 3
Q1 1 2 3 PBSS5580PA 0.7015
Q2 11 2 3 PBSS5580PA 0.2985
D1 1 2 DIODE 
D2 11 2 DIODE
RQ 1 11 1.947 
*
.MODEL PBSS5580PA PNP 
+ IS = 1.658E-012 
+ NF = 0.9695 
+ ISE = 1.509E-013 
+ NE = 1.36 
+ BF = 282.2 
+ IKF = 5.031 
+ VAF = 51 
+ NR = 0.9689 
+ ISC = 1.38E-013 
+ NC = 1.118 
+ BR = 97.93 
+ IKR = 0.4854 
+ VAR = 27.57 
+ RB = 7 
+ IRB = 0.0015 
+ RBM = 1.51 
+ RE = 0.02372 
+ RC = 0.01387 
+ XTB = 0 
+ EG = 1.11 
+ XTI = 3 
+ CJE = 6.56E-010 
+ VJE = 0.7269 
+ MJE = 0.3747 
+ TF = 1.55E-009 
+ XTF = 6 
+ VTF = 2 
+ ITF = 1 
+ PTF = 0 
+ CJC = 1.63E-010 
+ VJC = 0.8083 
+ MJC = 0.4803 
+ XCJC = 1 
+ TR = 1.6E-009 
+ CJS = 0 
+ VJS = 0.75 
+ MJS = 0.333 
+ FC = 0.9 
.MODEL DIODE D 
+ IS = 2.05E-014 
+ N = 1.013 
+ BV = 1000 
+ IBV = 0.001 
+ RS = 742.5 
+ CJO = 0 
+ VJ = 1 
+ M = 0.9 
+ FC = 0 
+ TT = 0 
+ EG = 1.1 
+ XTI = 3 
.ENDS
*