***********************************************************
*
* PBSS4580PA
*
* Nexperia
*
* Low VCEsat NPN (BISS) Transistor
* IC   = 5,6 A
* VCEO = 80 V 
* hFE  = typ. 265 @ 2V/2A
*
*
*
*
* Package pinning does not match Spice model pinning.
* Package: SOT 1061
* 
* Package Pin 1: Base
* Package Pin 2: Emitter
* Package Pin 3: Collector
*
*
* Extraction date (week/year): 20/2009
* Spicemodel does not include temperature dependency
*
*********************************************************
*#
* Please note: Diodes D1/D2, Transistor Q2 and Resistor RCQ 
* are dedicated to improve modeling of quasi
* saturation area and reverse mode operation
* and do not reflect physical devices
*
.SUBCKT PBSS4580PA 1 2 3
Q1 1 2 3 PBSS4580PA 0.8913  
Q2 11 2 3 PBSS4580PA 0.1087
D1 2 1 DIODE 
D2 2 11 DIODE
RCQ 11 1 18.03 
*  
.MODEL PBSS4580PA NPN 
+ IS = 1.676E-012 
+ NF = 0.9647 
+ ISE = 2.594E-014 
+ NE = 1.301 
+ BF = 480 
+ IKF = 3.374 
+ VAF = 33.3 
+ NR = 0.9648 
+ ISC = 3.959E-013 
+ NC = 1.352 
+ BR = 95.07 
+ IKR = 40.56 
+ VAR = 29.35 
+ RB = 9.927 
+ IRB = 0.0007 
+ RBM = 1.9 
+ RE = 0.03 
+ RC = 0.01048 
+ XTB = 0 
+ EG = 1.11 
+ XTI = 3 
+ CJE = 7.501E-010 
+ VJE = 0.7269 
+ MJE = 0.3563 
+ TF = 7.7E-010 
+ XTF = 8 
+ VTF = 2 
+ ITF = 0.8 
+ PTF = 0 
+ CJC = 7.251E-011 
+ VJC = 0.19 
+ MJC = 0.3201 
+ XCJC = 1 
+ TR = 9E-009 
+ CJS = 0 
+ VJS = 0.75 
+ MJS = 0.333 
+ FC = 0.98 
.MODEL DIODE D 
+ IS = 4.382E-014 
+ N = 0.9624 
+ BV = 1000 
+ IBV = 0.001 
+ RS = 1496 
+ CJO = 0 
+ VJ = 1 
+ M = 0.5 
+ FC = 0 
+ TT = 0 
+ EG = 1.11 
+ XTI = 3 
.ENDS
*