***********************************************************
*
* PBSS4540Z
*
* Nexperia
*
* Low VCEsat NPN (BISS) Transistor
* IC   = 5 A
* VCEO = 40 V 
* hFE  = min. 300 typ. 500 @ 2V/500mA
*
*
*
*
* Package pinning does not match Spice model pinning.
* Package: SOT 223
* 
* Package Pin 1: Base
* Package Pin 2: Collector
* Package Pin 3: Emitter
* Package Pin 4: Collector
*
* #
* Spicemodel does not include temperature dependency
*
**********************************************************
*#
* Please note: Diode D1 is dedicated to improve modeling in reverse
* mode of operation and does not reflect a physical device.
*
.SUBCKT PBSS4540Z 1 2 3
Q1 1 2 3 PBSS4540Z
D1 2 1 DIODE
*
.MODEL PBSS4540Z NPN
+ IS = 2.317E-12
+ NF = 0.9656
+ ISE = 3.506E-14
+ NE = 1.401
+ BF = 530
+ IKF = 26
+ VAF = 110.5
+ NR = 0.9655
+ ISC = 3.877E-14
+ NC = 1.03
+ BR = 300
+ IKR = 7
+ VAR = 13.2
+ RB = 2.6
+ IRB = 0.000183
+ RBM = 1.3
+ RE = 0.034
+ RC = 0.022
+ XTB = 0
+ EG = 1.11
+ XTI = 3
+ CJE = 1.044E-09
+ VJE = 0.55
+ MJE = 0.3176
+ TF = 1.35E-09
+ XTF = 30
+ VTF = 1.7
+ ITF = 1.6
+ PTF = 0
+ CJC = 2.02E-10
+ VJC = 0.627
+ MJC = 0.45
+ XCJC = 1
+ TR = 2E-09
+ CJS = 0
+ VJS = 0.75
+ MJS = 0.333
+ FC = 0.08
.MODEL DIODE D
+ IS = 1E-15
+ N = 1
+ BV = 1000
+ IBV = 0.001
+ RS = 1.298
+ CJO = 0
+ VJ = 1
+ M = 0.5
+ FC = 0
+ TT = 0
+ EG = 1.11
+ XTI = 3
.ENDS
*