**********************************************************
*
* PBSS4240Z
*
* Nexperia
*
* Low VCEsat NPN transistor
* IC   = 2 A
* VCEO = 40 V 
* hFE  = min. 300 @ 5V/500mA
*
* 
*
*
* Package pinning does not match Spice model pinning.
* Package: SOT 223
* 
* Package Pin 1:   Base
* Package Pin 2/4: Collector
* Package Pin 3:   Emitter
* 
*
* Extraction date (week/year): 18/2014
* Spicemodel includes temperature dependency
*
**********************************************************
*#
* Please note: Diode D1, Transistor Q2 and Resistor RQ
* are dedicated to improve modeling of quasi
* saturation area and reverse mode operation
* and do not reflect physical devices.
*
.SUBCKT PBSS4240Z 1 2 3
Q1 1 2 3 MAIN 0.605
Q2 11 2 3 MAIN 0.395
RQ 1 11 4.764
D1 2 1 DIODE
*
.MODEL MAIN NPN
+ IS = 1.754E-013
+ NF = 1.007
+ ISE = 2.27E-014
+ NE = 1.598
+ BF = 530
+ IKF = 1.409
+ VAF = 50.82
+ NR = 1.007
+ ISC = 1.169E-014
+ NC = 1.254
+ BR = 115
+ IKR = 1.312
+ VAR = 60.12
+ RB = 21.5
+ IRB = 0.00075
+ RBM = 10
+ RE = 0.07608
+ RC = 0.03473
+ XTB = 1.631
+ EG = 1.11
+ XTI = 6.701
+ CJE = 1.107E-010
+ VJE = 0.7273
+ MJE = 0.3482
+ TF = 5.3E-010
+ XTF = 18
+ VTF = 1
+ ITF = 3
+ PTF = 0
+ CJC = 2.611E-011
+ VJC = 0.4078
+ MJC = 0.2731
+ XCJC = 1
+ TR = 6.5E-009
+ CJS = 0
+ VJS = 0.75
+ MJS = 0.333
+ FC = 0.98
.MODEL DIODE D
+ IS = 2.183E-015
+ N = 0.9942
+ BV = 1000
+ IBV = 0.001
+ RS = 360.7
+ CJO = 0
+ VJ = 1
+ M = 0.9
+ FC = 0
+ TT = 0
+ EG = 1.1
+ XTI = 3
.ENDS
*