***********************************************************
*
* PBSS4230PAN
*
* Nexperia
*
* Double Low VCEsat NPN/NPN Transistor
* IC   = 2 A
* VCEO = 30 V 
* hFE  = typ. 350  @ 2V/500mA
*
* 
*
*
* Package pinning does not match Spice model pinning.
* Package: SOT 1118
* 
* Package Pin 1/4: Emitter   TR1/TR2
* Package Pin 2/5: Base      TR1/TR2
* Package Pin 6/3: Collector TR1/TR2
* Package Pin 7/8: Collector TR1/TR2
*
* Extraction date (week/year): 43/2012
* Spicemodel does not include temperature dependency
*
**********************************************************
*#
* Please note: The following model is to be used twice in 
* schematic due to equality of both Transistors.
*
* Diode D1 is dedicated to improve modeling in reverse
* mode of operation and does not reflect a physical device.
*
.SUBCKT PBSS4230PAN 1 2 3
Q1 1 2 3 MAIN 
D1 2 1 DIODE 
*
.MODEL MAIN NPN
+ IS = 1.461E-013
+ NF = 0.9628
+ ISE = 8.291E-016
+ NE = 1.172
+ BF = 433
+ IKF = 2.207
+ VAF = 28.73
+ NR = 0.9629
+ ISC = 2.622E-017
+ NC = 1.037
+ BR = 175.8
+ IKR = 1.242
+ VAR = 39
+ RB = 32
+ IRB = 0.0008
+ RBM = 1.1
+ RE = 0.04181
+ RC = 0.05834
+ XTB = 0
+ EG = 1.11
+ XTI = 3
+ CJE = 1.88E-010
+ VJE = 0.6608
+ MJE = 0.328
+ TF = 1.343E-009
+ XTF = 13.16
+ VTF = 25
+ ITF = 3.093
+ PTF = 0
+ CJC = 3.431E-011
+ VJC = 0.1495
+ MJC = 0.2054
+ XCJC = 1
+ TR = 1E-008
+ CJS = 0
+ VJS = 0.75
+ MJS = 0.333
+ FC = 0.8177
.MODEL DIODE D
+ IS = 2.082E-015
+ N = 0.9929
+ BV = 1000
+ IBV = 0.001
+ RS = 857.2
+ CJO = 0
+ VJ = 1
+ M = 0.5
+ FC = 0
+ TT = 0
+ EG = 1.11
+ XTI = 3
.ENDS
*