*
*******************************************
*
*BZB984-C2V4
*
*NXP Semiconductors
*
*Voltage regulator double diodes
*
*
*
*
* 
*VFmax = 0,9V  @ IF = 10mA
*
*
*VZmax = 2,6V  @ IZ   = 5mA
*
*
*
*PZSM  = 40W
* 
*
*
*Package pinning does not match Spice model pinning.
*Package: SOT663
*
*Package Pin 1: cathode      D1   
*Package Pin 2: cathode      D2 
*Package Pin 3: common anode
*
*
*Extraction date (week/year): 02/2016
*Simulator: SPICE3
*
*******************************************
*#
* Please note: This device is an array and the
* symbol has to be placed twice on the schematic
*
.SUBCKT BZB984-C2V4 1 2
R1 1 2 1E+008
D1 1 2
+ DIODE1
D2 3 1
+ DIODE2
VZ 2 3 0.01
* 
*The resistor R1, the diode D2 and   
*VZ do not reflect  
*physical devices but improve 
*only modeling in the reverse 
*mode of operation.
*
.MODEL DIODE1 D
+ IS = 8E-016
+ N = 1.03
+ BV = 2.6
+ IBV = 0.005
+ RS = 0.3
+ CJO = 1.21E-010
+ VJ = 0.8
+ M = 0.355
+ FC = 0.5
+ TT = 0
+ EG = 1.1
+ XTI = 3
.MODEL DIODE2 D
+ IS = 1E-009
+ N = 4.5
+ RS = 120
.ENDS
*