*BUK7611_55A device 

.SUBCKT BUK7611_55A D G S 
X1 S 5 bondwire params: length=4m dia=350u
X2 S 5 bondwire params: length=4m dia=350u
X3 S 5 bondwire params: length=4m dia=350u
X4 G 1 bondwire params: length=4m dia=125u
Rg 1 4 0.7
Rdgd 2 3 1e9  
Rcgd 3 4 1e9  
Rcgs 4 5 1e8
Dgd 3 2 Dgd 
Cgd 3 4 5.5e-9
Cgs 4 5 4.4e-9
M1 2 4 5 5 Mint           
M2 4 2 3 3 Mdg
Rd 2 D Rtemp1 1.1e-3
Dsd 5 6 Dsd
Rdsd 6 D Rtemp1 0.1e-3
Rlsd 5 D Rtemp2 3.93e10
.MODEL Mint NMOS(Vto=3.23 Kp=18 Nfs=1e11 Eta=1e3
+ Level=3 L=1e-4 W=1e-4 Gamma=0 Phi=0.6  Is=1e-24
+ Js=0 Pb=0.8  Cj=0 Cjsw=0 Cgso=0 Cgdo=0 Cgbo=0
+ Tox=1e-7 Xj=0 
+ U0=0 )          
.MODEL Dsd D(Bv=62 Ibv=250e-6 Rs=3.4e-3 Is=2.54e-12
+ N=1 M=0.5 VJ=1 Fc=0.5 Cjo=2.16e-9 Tt=41e-9)
.MODEL Dgd D(Cjo=2e-09 Rs=1e-3
+ Is=1e-14 M=0.4 N=1 VJ=1 Fc=0.5)
.MODEL Mdg NMOS(Vto=1e-3 Kp=10 Nfs=0 Eta=0
+ Level=3 L=1e-4 W=1e-4 Gamma=0 Phi=0.6  Is=1e-24
+ Js=0 Pb=0.8  Cj=0 Cjsw=0 Cgso=0 Cgdo=0 Cgbo=0
+ Tox=1e-7 Xj=0 
+ U0=0 )          
.MODEL Rtemp1 RES(TC1=5.16e-3)
.MODEL Rtemp2 RES(TC1=-0.05)
.ENDS 

.SUBCKT bondwire 1 3 params: length=1m dia=1u
L1 1 2 {2*length*(log(4*length/dia)-1)*1e-7}
R1 2 3 {length*2.8e-8/(3.1415*(dia/2)^2)}
R2 1 2 {(2*length*(log(4*length/dia)-1)*1e-7)*2*3.1415*50e6}
.ENDS