**********************************************************
*
* BC807K_40
*
* Nexperia
*
* General purpose PNP transistor
* IC   = 500 mA
* VCEO = 45 V 
* hFE  = 250 - 600 @ 1V/100mA
* 
*
*
*
* Package pinning does not match Spice model pinning.
* Package: SOT 23
* 
* Package Pin 1: Base
* Package Pin 2: Emitter
* Package Pin 3: Collector
* 
*
* Extraction date (week/year): 40/2017 
* Spicemodel includes temperature dependency
*
**********************************************************
*#
* Please note: Transistor Q2 and Resistor RQ
* are dedicated to improve modeling of quasi
* saturation area and reverse mode operation
* and do not reflect physical devices.
*
.SUBCKT BC807K_40 1 2 3
Q1 1 2 3 MAIN 0.7241
Q2 11 2 3 MAIN 0.2759
RQ 1 11 15.88
*
.MODEL MAIN PNP
+ IS = 1.419E-013
+ NF = 0.9636
+ ISE = 4.613E-014
+ NE = 1.583
+ BF = 541
+ IKF = 0.331
+ VAF = 27.34
+ NR = 0.9629
+ ISC = 1.353E-014
+ NC = 1.366
+ BR = 32.45
+ IKR = 0.1039
+ VAR = 13.26
+ RB = 35
+ IRB = 0.0025
+ RBM = 0.7
+ RE = 0.07528
+ RC = 0.09864
+ XTB = 1.974
+ EG = 1.11
+ XTI = 8.377
+ CJE = 4.547E-011
+ VJE = 0.6642
+ MJE = 0.38
+ TF = 8.5E-010
+ XTF = 1.859
+ VTF = 3.813
+ ITF = 0.4393
+ PTF = 0
+ CJC = 1.95E-011
+ VJC = 0.5518
+ MJC = 0.45
+ XCJC = 0.459
+ TR = 2.35E-008
+ CJS = 0
+ VJS = 0.75
+ MJS = 0.333
+ FC = 0.75
.ENDS
*