*
*******************************************
*
*BAV99QA
*
*NXP Semiconductors
*
*Dual series high-speed switching diode
*
*
*VRmax = 90V
*
* 
*
*IRmax = 0,5ľA @ VR = 80V
*
*
*
*
*
*  
*
*
*
*Package pinning does not match Spice model pinning.
*Package: SOT1215 (DFN1010D-3)
*
*Package Pin 1: Anode   D1
*Package Pin 2: Cathode D2
*Package Pin 3: Cathode D1; Anode D2
*Package Pin 4: Cathode D1; Anode D2
*
*Extraction date (week/year): 14/2016
*Simulator: SPICE3
*
*******************************************
*#
.SUBCKT BAV99QA 1 2 3
*
*The resistors R1,R2 and the diodes D2, D4   
*do not reflect physical devices but improve   
*only modeling in the reverse mode of operation.
*
R1 1 3 5E+009
R2 3 2 3.6E+009
D1 1 3 DIODE1
D2 1 3 DIODE2
D3 3 2 DIODE3
D4 3 2 DIODE4
*
.MODEL DIODE1 D
+ IS = 8E-010
+ N = 1.7
+ BV = 130
+ IBV = 5E-006
+ RS = 2.6
+ CJO = 4.239E-013
+ VJ = 0.32
+ M = 0.024
+ FC = 0.5
+ TT = 0
+ EG = 1.1
+ XTI = 3
.MODEL DIODE2 D
+ IS = 2E-009
+ N = 1.9
+ RS = 200
.MODEL DIODE3 D
+ IS = 6.8E-010
+ N = 1.71
+ BV = 103
+ IBV = 3E-005
+ RS = 1.1
+ CJO = 1.76E-012
+ VJ = 0.9
+ M = 0.22
+ FC = 0.5
+ TT = 0
+ EG = 1.1
+ XTI = 3
.MODEL DIODE4 D
+ IS = 1.5E-010
+ N = 1.39
+ RS = 280
.ENDS
*