***********************************************************
*
* BAS16VY
*
* Nexperia
*
* High-speed switching diodes
* IFmax = 200mA
* VRmax = 100V
* VFmax = 1,25V  @ IF = 150mA
* IRmax = 0,5µA  @ VR = 80V
*
*
* Package pinning does not match Spice model pinning.
* Package: SOT363 (SC-88)
* 
* Package Pin 1;4: Anode;Cathode D1;D3
* Package Pin 2;5: Anode;Cathode D2;D2
* Package Pin 3;6: Anode;Cathode D3;D1
*
*
*
* Extraction date (week/year): #
* Simulator: SPICE3
*
***********************************************************
*
* Please note: This device is an array and the
* symbol has to be placed three times on the schematic.
*
* The resistor R1 and the diode D2  
* do not reflect physical devices.
* Instead they improve modeling in the 
* forward and reverse mode of operation.
*
.SUBCKT BAS16VY 1 2
R1 1 2 5E+009   
D1 1 2 DIODE1
D2 1 2 DIODE2
*
 .MODEL DIODE1 D 
 + IS = 3.9E-009 
 + N = 1.9       
 + BV = 125.9    
 + IBV = 1.738E-008      
 + RS = 1.1      
 + CJO = 4.42E-013       
 + VJ = 0.124    
 + M = 0.024     
 + FC = 0.5      
 + TT = 0
 + EG = 1.11      
 + XTI = 3       
 .MODEL DIODE2 D 
 + IS = 3E-015   
 + N = 1.1       
 + RS = 280      
 .ENDS
*