**********************************************************
*
* 2PA1774RM
*
* Nexperia
*
* General purpose PNP transistor
* IC   = 100 mA
* VCEO = 40 V 
* hFE  = 180 - 390 @ 6V/1mA
*
*
*
*
* Package pinning does not match Spice model pinning.
* Package: SOT 883
* 
* Package Pin 1: Base
* Package Pin 2: Emitter
* Package Pin 3: Collector
*
*  
* Extraction date (week/year): 14/2019       
* Spicemodel includes temperature dependency
*
**********************************************************
*#
* Please note: Diode D1, Transistor Q2 and Resistor RQ 
* are dedicated to improve modeling of quasi
* saturation area and reverse mode operation
* and do not reflect physical devices.
*
.SUBCKT 2PA1774RM 1 2 3
Q1 1 2 3 Transistor 0.9009
Q2 11 2 3 Transistor 0.09907
RQ 11 1 210.3
D1 1 2 Diode
*
.MODEL Transistor PNP
+ IS = 1.076E-014
+ NF = 0.9774
+ ISE = 4.359E-015
+ NE = 1.373
+ BF = 249
+ IKF = 0.05826
+ VAF = 27.87
+ NR = 0.9763
+ ISC = 4.261E-015
+ NC = 1.09
+ BR = 10.95
+ IKR = 4.364
+ VAR = 25
+ RB = 800
+ IRB = 1E-005
+ RBM = 0.765
+ RE = 0.1943
+ RC = 0.4634
+ XTB = 1.927
+ EG = 1.11
+ XTI = 10.73
+ CJE = 9.442E-012
+ VJE = 0.7232
+ MJE = 0.4648
+ TF = 1.2E-009
+ XTF = 4.859
+ VTF = 3.813
+ ITF = 0.4393
+ PTF = 0
+ CJC = 6.211E-012
+ VJC = 0.6054
+ MJC = 0.391
+ XCJC = 0.459
+ TR = 1.75E-007
+ CJS = 0
+ VJS = 0.75
+ MJS = 0.333
+ FC = 0.99
.MODEL Diode D
+ IS = 3.431E-017
+ N = 0.986
+ BV = 1000
+ IBV = 0.001
+ RS = 0.2713
+ CJO = 0
+ VJ = 1
+ M = 0.5
+ FC = 0
+ TT = 0
+ EG = 1.11
+ XTI = 3
.ENDS
*